//import processing.opengl.*;
import procontroll.*;
import net.java.games.input.*;
import traer.physics.*;
import krister.Ess.*;

/** 
  Use the arrow keys for movement, 'a' for the sucking force, 's' for the blowing force 
*/

// ----------- GAME SETTINGS ----------------- //

int playerSize = 10; // radius in pixels
int playerSpeed = 8;  // move amount in pixels per frame TODO: make this time based

int kickInterval = 5; // spawn a kick pulser every #th kick
int kickRadius = 31; // in pixels
float kickWeight = 0.8f;
color kickColor = color(255, 179, 40);

int snareInterval = 5; // spawn a snare pulser every #th snare
int snareRadius = 23; // in pixels
float snareWeight = 1.2f;
color snareColor = color(210, 41, 42);

int hatInterval = 5; // spawn a hat pulser every #th hat
int hatRadius = 17; // in pixels
float hatWeight = 1.5f;
color hatColor = color(255, 45, 139);

float pulseAmt = 1.3f; // percentage of how much larger they will get
int maxPulsers = 20; // maximum number of pulsers allowed on screen
float glowIntensity = 100;

float suckStrength = 3f; // larger number means stronger sucking
float blowStrength = 0.5f; // larger number means stronger blowing
                         
// ------------------- END GAME SETTINGS ----------------------- //

PFont arial;
PS2Controller gamepad;
ParticleSystem phys = new ParticleSystem(0, .2f);
Player pl;

Pulser puls;
Vector pulsers = new Vector(15, 15);
Iterator pIter;
Iterator pIterb;

Nest n;
Vector nests = new Vector(3, 0);
Iterator nIter;

Deathskull skull;
Vector skulls = new Vector(2, 0);
Iterator dIter;

SuckBlow sucker;
Vector suckers = new Vector(2, 0);
Iterator sIter;

AudioInput in;
BeatDetect beat;
int kickWait = 0;
int snareWait = 0;
int hatWait = 0;
int totalCaught = 0;
int score = 0;
boolean debug = false;
boolean screenStats = true;
boolean drawGlow = true;
boolean drawGhost = true;
boolean useGamepad = false;

void setup()
{
  // setup the environment
  size(1024, 768, P3D);
  background(0);
  noCursor();
  ellipseMode(CENTER_RADIUS);
  frameRate(30);
  arial = loadFont("ArialMT-24.vlw");
  textFont(arial); 
  
  if ( useGamepad )
  {
    // setup the gamepad
    gamepad = new PS2Controller(this);
    gamepad.leftStick.setMultiplier(playerSpeed);
    gamepad.leftStick.setTolerance(0.3f);
    gamepad.rightStick.setTolerance(0.15f);
    gamepad.invertRightY = true;
  }
  
  // create the player
  pl = new Player(phys.makeParticle(1, width/2, height/2, 0), playerSize, playerSpeed);
 
  // setup the sound
  Ess.start(this);
  in = new AudioInput(1024, 44100);
  beat = new BeatDetect(in.size, in.sampleRate);
  beat.detectMode("FREQ_ENERGY");
  beat.detectDetail(64);
  in.start();
}

void draw()
{
  if ( drawGhost )
  {
    fill(0, 90);
    rect(0, 0, width, height);
  }
  else
  {
    background(0);
  }
  phys.tick();
  
  // Update the player
  if ( useGamepad )
  {
    pl.move(gamepad.leftX(), gamepad.leftY());
    pl.suck( gamepad.L1.pressed() || gamepad.X.pressed() );
    pl.blow( gamepad.R1.pressed() || gamepad.O.pressed() );
  }
  else
  {
    pl.keyMove();
    pl.keySuck();
    pl.keyBlow();
  }
  
  // make new pulsers from beat if there are fewers than maxPulsers on the board
  if ( pulsers.size() < maxPulsers )
  {
    if ( beat.isKick() )
    {
      if ( kickWait == 0 )
      {
        if ( debug ) println("Adding a kick.");
        Pulser k = new Pulser(KICK);
        pulsers.add(k);
        kickWait = kickInterval;
      }
      else kickWait--;
    }
    
    if ( beat.isSnare() )
    {
      if ( snareWait == 0 )
      {
        if ( debug ) println("Adding a snare.");
        Pulser s = new Pulser(SNARE);      
        pulsers.add(s);
        snareWait = snareInterval;
      }
      else snareWait--;
    }
    
    if ( beat.isHat() )
    {
      if ( hatWait == 0 )
      {
        if ( debug ) println("Adding a hat.");
        Pulser h = new Pulser(HAT);        
        pulsers.add(h);
        hatWait = hatInterval;
      }
      else hatWait--;
    }
  }
  
  // make new nest, maybe
  if ( nests.size() < 3 && random(1) < 0.008)
  {
    // generate a possible position
    float x = random(100, width-100);
    float y = random(100, height-100);
    // check for overlap with existing nests
    for (int i = 0; i < nests.size(); i++)
    {
      Nest tmp = (Nest)nests.get(i);
      if ( dist(x, y, tmp.x(), tmp.y()) < 200 )
      {
        x = random(100, width-100);
        y = random(100, height-100);
        i = -1;
      }
    }
    nests.add(new Nest(x, y));
  }
  
  // manage the nests
  nIter = nests.iterator();
  while ( nIter.hasNext() )
  {
    n = (Nest)nIter.next();
    if ( n.age() > 8 ) 
    {
      nIter.remove();
      n.kill();
    }
    else n.render();    
  }
  
  // make new deathskull, maybe
  if ( skulls.size() < 2 && random(1) < 0.008 )
  {
    skulls.add(new Deathskull());
  }
  
  // manage the deathskulls
  dIter = skulls.iterator();
  while ( dIter.hasNext() )
  {
    skull = (Deathskull)dIter.next();
    if ( skull.isOffScreen() ) skull.kill();
    if ( skull.isDead() ) dIter.remove();
    else 
    {
      skull.chase();
      skull.render();
    }
  }
  
  // make a new sucker/blower, maybe
  if ( suckers.size() < 2 && random(1) < 0.008 )
  {
    suckers.add(new SuckBlow());
  }
  
  // manage the sucker/blowers
  sIter = suckers.iterator();
  while ( sIter.hasNext() )
  {
    sucker = (SuckBlow)sIter.next();
    if ( sucker.isDead() ) sIter.remove();
    else
    {
      sucker.update();
      sucker.render();
    }
  }
  
  // pulsing, nest interaction, player interaction, enemy interaction,
  // collision and rendering
  pIter = pulsers.iterator();
  while ( pIter.hasNext() )
  {
    puls = (Pulser)pIter.next();
    if ( puls.isDead() )
    {
      pIter.remove();
      continue;
    }
    if ( puls.dying )
    {
      puls.render();
      puls.deathTick();
      continue;
    }
    if ( puls.isOffScreen() )
    {        
      puls.kill();
      continue;
    }
    
    nIter = nests.iterator();
    while ( nIter.hasNext() )
    {
      n = (Nest)nIter.next();
      if ( !puls.caught ) n.tryCatch(puls);
    }
    if ( puls.isDead() ) continue;
    
    if ( puls.caught ) 
    {
      puls.caughtTick();
      puls.setMood(GLEE);
    }
    
    puls.rendered = false;
    puls.look(puls.x(), puls.y());
    if ( puls.isMoving() ) puls.setMood(HAPPY);
    else puls.resetMood();
    
    // pulse according to type
    switch(puls.type)
    {
      case KICK: if ( beat.isKick() ) puls.pulse(); break;
      case SNARE: if ( beat.isSnare() ) puls.pulse(); break;
      case HAT: if ( beat.isHat() ) puls.pulse(); break;
    }  
    
    // interact with player
    if ( puls.distFrom(pl) < 200 && !puls.caught )
    {
      puls.setMood(HOPEFUL);
      puls.look(pl.x(), pl.y());
      puls.playerCollide();
      if ( pl.isSucking() && pl.withinRange(puls) ) 
      {
        puls.attach();
        if ( puls.attachedFor() > 5 ) puls.setMood(VORACIOUS);
        else  puls.setMood(HAPPY);
      }
      else puls.detach();
      if ( pl.isBlowing() && pl.withinRange(puls) )
      {
        float cx = puls.x() - pl.x();
        float cy = puls.y() - pl.y();
        if ( puls.mood() == VORACIOUS ) puls.setVelocity(2*blowStrength*cx, 2*blowStrength*cy);
        else puls.setVelocity(blowStrength*cx, blowStrength*cy);
        puls.setMood(HAPPY);
      }
    }    
    
    // interact with enemies
    
    dIter = skulls.iterator();
    while ( dIter.hasNext() )
    {
      skull = (Deathskull)dIter.next();
      if ( puls.isAttached() )
      {
        puls.skullBounce(skull);
      }
      else if ( puls.distFrom(skull) < 200 )
      {
        if ( puls.isMoving() )
        {
          puls.skullBounce(skull);
        }
        else
        {
          puls.look(skull.x(), skull.y());
          puls.setMood(AFRAID);
          skull.target(puls);
        }
      }       
    }
    
    sIter = suckers.iterator();
    while ( sIter.hasNext() )
    {
      sucker = (SuckBlow)sIter.next();
      if ( puls.distFrom(sucker) < 200 )
      {
        if ( sucker.sucking && !puls.caught )
        {
          puls.look(sucker.x(), sucker.y());
          puls.setMood(AFRAID);
          sucker.suck(puls);
          if ( puls.distFrom(sucker) < puls.getRadius() + 30 ) 
          {
            puls.points = -50;
            score -= 50;
            puls.kill();
          }
        }
        else if ( sucker.blowing && !puls.caught )
        {
          sucker.blow(puls);
        }
        else
        {
          puls.suckerBounce(sucker);
        }
      }
    }
    
    puls.wallBounce();
    
    // collide with other pulsers
    pIterb = pulsers.iterator();
    while ( pIterb.hasNext() )
    {
      puls.pulseBounce((Pulser)pIterb.next());
    }
    
    puls.render();
  }
  
  
  pl.render();
  
  fill(255, 0, 0);
  text("Total saved: " + totalCaught, 800, 30);
  text("Score: " + score, 800, 60);
  if ( screenStats )
  {
    fill(255, 0, 0);
    text("Frame Rate: " + frameRate, 5, 30);
    text("Total pulsers: " + pulsers.size(), 5, height - 15);
  }
  if ( debug )
  {
    println(Runtime.getRuntime().freeMemory());
    println("End draw, frame " + frameCount);
  }
}

void keyPressed()
{  
  if ( key == CODED )
  {
    switch(keyCode)
    {
      case UP:
        pl.up = true;
        break;
      case RIGHT:
        pl.right = true;
        break;
      case DOWN:
        pl.down = true;
        break;
      case LEFT:
        pl.left = true;
        break;
    }
  }
  else
  {
    if ( key == 'a' ) pl.suck = true;
    else if ( key == 's' ) pl.blow = true;
    else if ( key == 'g' ) drawGlow = !drawGlow;
  }
}

void keyReleased()
{  
  if ( key == CODED )
  {
    switch(keyCode)
    {
      case UP:
        pl.up = false;
        break;
      case RIGHT:
        pl.right = false;
        break;
      case DOWN:
        pl.down = false;
        break;
      case LEFT:
        pl.left = false;
        break;
    }
  }
  else
  {
    if ( key == 'a' ) pl.suck = false;
    else if ( key == 's' ) pl.blow = false;
  }
}


public void audioInputData(AudioInput in)
{
  beat.detect(in);
}

public void stop()
{
  Ess.stop();
  super.stop();
}